Amiga Plus 2002 #3/Amiga Plus CD - 2002 - No. 03.iso/AmigaPlus/Tools/Development/envCPP31/c++/rexx/createproject.rexx

OS/2 REXX Batch file | 2002-01-01 | 33.0 KB | 1,067 lines

/* rexx macro */

options results                             /* enable return codes     */

if (left(address(), 6) ~= "GOLDED") then    /* not started by GoldEd ? */

    address 'GOLDED.1'

'LOCK CURRENT RELEASE=4'                    /* lock GUI, gain access   */

if (RC ~= 0) then

    exit

options failat 6                            /* ignore warnings         */

signal on syntax                            /* ensure clean exit       */

/* ------------------------- INSERT YOUR CODE HERE: -------------------- */

/* INPUTS: ACTION/K/A,CMODE/K (supported values for CMODE: SAS-C,VBCC,GCC,STORMC,GENERIC) */

parse upper arg ACTION CMODE .

if (ACTION = "") then

    ACTION = "ASK"

if (CMODE = "") then

    CMODE = "GENERIC"

'QUERY CAT'

if (RESULT = "deutsch") then do

    STRING.sNOTINSTALLED      = "Support für diesen Compiler wurde nicht|installiert:"
    STRING.sCONFIGURATION     = "C/C++-Umgebung"
    STRING.sNEWPROJECT        = "Neues Projekt"
    STRING.sMENU              = "Neues Projekt anlegen oder ein|bestehendes Verzeichnis mit C-Quelltexten|übernehmen und unter die Kontrolle von|GNU make stellen (makefile hinzufügen) ?"
    STRING.sNEWTAKEOVERCANCEL = "!Neues Projekt|_Makefile hinzufügen|Abbre_chen"
    STRING.sNAME              = "Projektname"
    STRING.sPROJECTNAME       = "Projektname auswählen (unter diesem Namen*nwird das ausführbare Programm erzeugt):"
    STRING.sUNNAMED           = "unbenannt"
    STRING.sBADNAME           = "Unerlaubte(s) Zeichen im Namen !"
    STRING.sPROJECTFOLDER     = "Projektordner hier anlegen..."
    STRING.sERROREXISTS       = "Ein Projekt mit diesem Namen existiert schon !"
    STRING.sOPTIONSERR        = "Kann Compileroptionen nicht speichern !"
    STRING.sEMPTYCREATED      = "Ein leeres Projekt wurde angelegt."
    STRING.sSHOW              = "!Anzeigen|Makefile zeigen|Beenden"
    STRING.sMAKEMAKEERROR     = "Makefile konnte nicht erzeugt werden !"
    STRING.sTAKEOVER          = "Makefile hier erzeugen..."
    STRING.sCONTROLLED        = "Das Verzeichnis bedindet sich schon unter|der Kontrolle eines GNU-Makefiles. Makefile|beibehalten oder ersetzen ?"
    STRING.sKEEPREPLACE       = "!Beibehalten|_Ersetzen|Abbre_chen"
    STRING.sSELECTHELP        = "Wählen Sie im folgenden Schritt die Quelltexte|aus, die zum Projekt gehören. Normalerweise sind|das alle Quelltexte im Verzeichnis (Kopf ALLE).||Hinweis: Zur Mehrfachauswahl die Umschalttaste|(SHIFT) beim Auswählen gedrückt halten !"
    STRING.sSOURCES           = "Quelltexte auswählen..."
    STRING.sREQUIRED          = "Es muss mindestens ein Quelltext in das|Projekt übernommen werden !"
    STRING.sASSIMILATED       = "Das Projekt wurde übernommen und unter|die Kontrolle von GNU make gestellt."
    STRING.sSHOWMAKEFILE      = "!Makefile zeigen|Beenden"
    STRING.sCONFIGREADERR     = "Kann Konfiguration nicht lesen !"
    STRING.sCONFIGHELP        = "Bevor das erste Projekt für Ihren Compiler*nerzeugt werden kann, müssen die compiler-*nspezifischen Einstellungen konfiguriert*nwerden.*n*nDie notwendigen Informationen finden Sie*nin der Dokumentation Ihres Compilers."
    STRING.sCONTINUE          = "!Weiter...|Abbre_chen"
    STRING.sCONTINUECOMPILER  = "!Mit Compilerauswahl fortfahren...|Abbre_chen"
    STRING.sOTHER             = "Anderer Compiler"
    STRING.sCOMPILERFOLDER    = "Geben Sie an, in welchem Verzeichnis*nsich die C/C++-Compilerumgebung befindet:"
    STRING.sCOMPILERMISSING   = "Compiler nicht gefunden !"
    STRING.sSTDHEADER         = "Geben Sie an, in welchem Verzeichnis sich die*nStandard-Header befinden (damit sind die mit*ndem Compiler gelieferten ISO-C-Header wie*nbeispielsweise <stdio.h> gemeint):"
    STRING.sSTDHEADERMISSING  = "Standard-Header nicht gefunden !"
    STRING.sNDKHEADER         = "Geben Sie an, in welchem Verzeichnis sich*ndie AmigaOS-Header befinden (die Angabe*nan dieser Stelle wird nur zum Verfolgen*nder Abhängigkeiten benutzt, nicht zum*nCompilieren):"
    STRING.sNDKHEADERMNISSING = "AmigaOS3-Header nicht gefunden !"
    STRING.sCOMPILE           = "Geben Sie an, mit welcher Befehlszeile ein*nQuelltext in eine Objektdatei (**.o) über-*nsetzt werden kann.*n*nIn der Befehlszeile können die Platzhalter*n%%src (stellvertretend für Name des Quell-*ntextes) und %%obj (stellvertretend für Name*nder Objektdatei) verwendet werden."
    STRING.sLINK              = "Geben Sie an, mit welcher Befehlszeile die*nObjektdateien (**.o) zu einem ausführbaren*nProgramm gelinkt werden.*n*nIn der Befehlszeile können die Platzhalter*n%%objs (stellvertretend für die Namen der*nObjektdateien) und %%exe (stellvertretend*nfür den Namen des Programms) verwendet*nwerden."
    STRING.sCONFIGSAVEERR     = "Kann Konfiguration nicht speichern !"
    STRING.sCONFIGCREATED1    = "Die Konfigurationsdatei für die C/C++-Umgebung"
    STRING.sCONFIGCREATED2    = "wurde erzeugt."
    STRING.sOKEDIT            = "!Weiter|_Bearbeiten|Abbre_chen"
end
else do

    STRING.sNOTINSTALLED      = "Support für this compiler has not been|installed:"
    STRING.sCONFIGURATION     = "C/C++ mode"
    STRING.sNEWPROJECT        = "Create Project"
    STRING.sMENU              = "Create a new project or put source codes|in an existing folder unter control of|GNU make (by adding a makefile) ?"
    STRING.sNEWTAKEOVERCANCEL = "!New Project|_Add Makefile|_Cancel"
    STRING.sNAME              = "Projektname"
    STRING.sPROJECTNAME       = "Choose a project name (this will be used*nas name for the generated executable):"
    STRING.sUNNAMED           = "unnamed"
    STRING.sBADNAME           = "Illegal character(s) in name !"
    STRING.sPROJECTFOLDER     = "Create project folder here..."
    STRING.sERROREXISTS       = "A project with this name already exists !"
    STRING.sOPTIONSERR        = "Can not save compiler options !"
    STRING.sEMPTYCREATED      = "An empty project has been created."
    STRING.sSHOW              = "!Edit|Show _makefile|_Done"
    STRING.sMAKEMAKEERROR     = "Failed to generate a makefile !"
    STRING.sTAKEOVER          = "Add makefile here..."
    STRING.sCONTROLLED        = "This project folder is already controlled by|a makefile. Do you want to keep the existing|makefile or should it be replaced ?"
    STRING.sKEEPREPLACE       = "!Keep|_Replace|_Cancel"
    STRING.sSELECTHELP        = "In the next step you will select the source|codes that belong to this project. Typically|that includes all source codes in the project|folder (simply click the the ALL button in|that case).||Note: SHIFT-click to select multiple files !"
    STRING.sSOURCES           = "Select source codes..."
    STRING.sREQUIRED          = "You must specify at least one source|code as part of this project !"
    STRING.sASSIMILATED       = "The project has been put under GNU|makefile control."
    STRING.sSHOWMAKEFILE      = "!Show Makefile|_Done"
    STRING.sCONFIGREADERR     = "Can not read configuration !"
    STRING.sCONFIGHELP        = "Before the first project can be created*nfor your compiler setup, some compiler-*nspecific options must be configured.*n*nYou can find the information required for*nconfiguration in the documention of your*ncompiler."
    STRING.sCONTINUE          = "!Continue...|_Cancel"
    STRING.sCONTINUECOMPILER  = "!Continue with compiler selection|_Cancel"
    STRING.sOTHER             = "Other Compiler"
    STRING.sCOMPILERFOLDER    = "Where is your C/C++ development package located ?"
    STRING.sCOMPILERMISSING   = "Compiler not found !"
    STRING.sSTDHEADER         = "Specify where the standard header files are*nlocated on your computer (this refers to the*nISO C header files shipped with your compiler,*nfor example <stdio.h>):"
    STRING.sSTDHEADERMISSING  = "Header files not found !"
    STRING.sNDKHEADER         = "Specify where the AmigaOS header files*nare located on your computer (the*ninformation entered here is used to check*ndependencies, not for compilation):"
    STRING.sNDKHEADERMNISSING = "AmigaOS3 header not found !"
    STRING.sCOMPILE           = "Specify the command line to be used for*ncompiling a source code into an object*nfile (**.o).*n*nThe command line specified here must be*nsuitable for appending (1) the object name*nand (2) the source code name in order to*ngenerate the compilation command.*n"
    STRING.sLINK              = "Specify the command line to be used for*nlinking a list of object files (*.o) into*nan executable.*n*nThe command line specified here must be*nsuitable for appending (1) the executable*nname and (2) the object names in order to*ngenerate the link command.*n"
    STRING.sCONFIGSAVEERR     = "Can not save configuration !"
    STRING.sCONFIGCREATED1    = "Configuration file for C/C++ environment"
    STRING.sCONFIGCREATED2    = "has been created."
    STRING.sOKEDIT            = "!Continue|_Edit|_Cancel"
end

call readcfg(CMODE)

if (ACTION = "ASK") then do

    'REQUEST VAR=ACTION TITLE="' || STRING.sCONFIGURATION || ' «' || CMODE || '»" BODY="' || STRING.sMENU || '" BUTTON="' || STRING.sNEWTAKEOVERCANCEL || '"'

    if (RESULT = 1) then do

        ACTION = "NEW"
    end
    else if (RESULT = 2) then do

        ACTION = "MAKEMAKE"
    end
    else do

        'UNLOCK'

        exit
    end
end

/* create a new project ? */

if (ACTION = "NEW") then do

    PROJECTNAME = ""

    do until (PROJECTNAME ~= "")

        'REQUEST STRING TITLE="' || STRING.sNEWPROJECT || '" BODY="' || STRING.sPROJECTNAME || '" OLD="' || STRING.sUNNAMED || '" VAR=PROJECTNAME'

        if ((PROJECTNAME ~= "") & (RC = 0)) then do

            if ((INDEX(PROJECTNAME, "/") ~= 0) | (INDEX(PROJECTNAME, "\") ~= 0) | (INDEX(PROJECTNAME, ":") ~= 0)) then do

                'REQUEST PROBLEM="' || STRING.sBADNAME || '"'

                PROJECTNAME = ""
            end
        end
        else do

            'UNLOCK'

            exit
        end
    end

    PATH = ""

    do until PATH ~= ""

        'REQUEST DIR SAVE TITLE="' || STRING.sPROJECTFOLDER || '" PATH="sys:" VAR=PATH'

        if ((RESULT ~= 0) & (RC = 0)) then do

            'EXPAND NAME="' || PATH || '" VAR=PATH'

            PATH = PATH || PROJECTNAME

            if (exists(PATH)) then do

                'REQUEST PROBLEM="' || STRING.sERROREXISTS || '"'

                PATH = ""
            end
        end
        else do

            'UNLOCK'

            exit
        end
    end

    /* create project folder */

    'FILE NEWDIR NAME="' || PATH || '"'

    if (RC = 0) then do

        R = pragma('D', PATH)

        /* create folders for objects and executable */

        'EXPAND NAME="' || PATH || '" VAR=PATH'

        'FILE NEWDIR NAME="' || PATH || 'bin"'

        if (RC = 0) then do

            PROJECTNAME = "bin/" || PROJECTNAME

            'FILE NEWDIR NAME="' || PATH || 'o"'

            if (RC = 0) then do

                OBJFOLDER = "o/"

                shell

                'copy "golded:add-ons/c++/samples/empty/main.c" main.c'

                'golded:add-ons/c++/tools/makemake/bin/makemake >makefile COMPILE="' || CONFIG.CFG_COMPILE || '" LINK="' || CONFIG.CFG_LINK || '" LOCAL RECURSELOCAL CONTINUE EXECUTABLE="' || PROJECTNAME || '" OBJECTS INCLUDE="' || CONFIG.CFG_INCLUDE || '" SDK="' || CONFIG.CFG_NDK || '" PREFIX="' || OBJFOLDER || '" FILES "main.c"'

                shell

                if (exists("makefile")) then do

                    /* create default options file */

                    call saveoptions(CONFIG.CFG_SOFTWARE)

                    /* load created source code */

                    'REQUEST BODY="' || STRING.sEMPTYCREATED || '" BUTTON="' || STRING.sSHOW || '"'

                    if ((RESULT ~= 0) & (RC = 0)) then do

                        if (RESULT = 1) then

                            'OPEN NEW SMART NAME="' || PATH || '/main.c"'

                        if (RESULT = 2) then

                            'OPEN NEW SMART NAME="' || PATH || '/makefile"'
                    end
                end
                else
                    'REQUEST PROBLEM="' || STRING.sMAKEMAKEERROR || '"'
            end
        end
    end
end

/* add makefile to a folder ? */

if (ACTION = "MAKEMAKE") then do

    'REQUEST DIR TITLE="' || STRING.sTAKEOVER || '" VAR=PATH'

    if ((PATH ~= "") & (RC = 0)) then do

        'EXPAND NAME="' || PATH || '" VAR=PATH'

        if (exists(PATH || "makefile")) then do

            'REQUEST BODY="' || STRING.sCONTROLLED || '" BUTTON="' || STRING.sKEEPREPLACE || '"'

            if ((RESULT ~= "2") | (RC ~= 0)) then do

                'UNLOCK'

                exit
            end
        end

        R = pragma('D', PATH)

        /* select sources to be put under control of makefile */

        'REQUEST BODY="' || STRING.sSELECTHELP || '" BUTTON="' || STRING.sCONTINUE || '"'

        if ((RESULT = 0) | (RC ~= 0)) then do

            'UNLOCK'

            exit
        end

        FILES = ""

        do until FILES ~= ""

            'REQUEST FILES PATTERN="#?.(c|cc|cpp|ccp|c++|a|asm|ass|i|s)" PATH="' || PATH || '" TITLE="' || STRING.sSOURCES || '" VAR=FILES'

            if (FILES = "") then

                'REQUEST PROBLEM="' || STRING.sREQUIRED || '"'

            if (RC ~= 0) then do

                'UNLOCK'

                exit
            end

        end

        /* process list of files: '"path/file" "path/file" ...' */

        MODULES = ""

        POS = 1
        MAX = length(FILES)

        do while (POS <= MAX)

            do while ((substr(FILES, pos, 1) = " ") | (substr(FILES, pos, 1) = '"'))

                POS = POS + 1

                if (POS > MAX) then

                    leave
            end

            START = POS
            LEN   = 0

            do while (POS <= MAX)

                DATA = substr(FILES, POS, 1)

                if ((DATA = ':') | (DATA = '/')) then do

                    START = POS + 1
                    POS   = POS + 1
                    LEN   = 0
                end
                else if (DATA = '"') then do

                    leave
                end
                else do

                    LEN = LEN + 1
                    POS = POS + 1
                end
            end

            if (LEN ~= 0) then do

                FULLPATH = substr(FILES, START, LEN)

                if (FILEPART = index(FULLPATH, ":")) then

                    FULLPATH = substr(FULLPATH, FILEPART + 1)

                do while (FILEPART = index(FULLPATH, "/"))

                    FULLPATH = substr(FULLPATH, FILEPART + 1)
                end

                if (MODULES == "") then
                    MODULES = FULLPATH
                else
                    MODULES = MODULES || " " || FULLPATH
            end
        end

        /* try to locate executable name */

        call getprojectname("")

        if (PROJECTNAME = "") then do

            do until (PROJECTNAME ~= "")

                'REQUEST STRING TITLE="' || STRING.sNAME || '" BODY="' || STRING.sPROJECTNAME || '" OLD="' || STRING.sUNNAMED || '" VAR=PROJECTNAME'

                if ((PROJECTNAME = "") | (RC ~= 0)) then do

                    'UNLOCK'

                    exit
                end
            end
        end

        /* generate makefile */

        COMMANDLINE = 'golded:add-ons/c++/tools/makemake/bin/makemake >makefile VERBOSE COMPILE="' || CONFIG.CFG_COMPILE || '" LINK="' || CONFIG.CFG_LINK || '" LOCAL RECURSELOCAL CONTINUE EXECUTABLE="' || PROJECTNAME || '" OBJECTS INCLUDE="' || CONFIG.CFG_INCLUDE || '" SDK="' || CONFIG.CFG_NDK || '" PREFIX="' || OBJFOLDER || '" FILES ' || MODULES

        'FIX VAR=COMMANDLINE'

        'RUN CMD="' || COMMANDLINE || '" DIR="' || PATH || '" SHANGHAI=10'

        if (exists("makefile")) then do

            if (OBJFOLDER = "o/") then

                'FILE NEWDIR NAME="' || PATH || 'o"'

            call saveoptions(CONFIG.CFG_SOFTWARE)

            if ((RESULT ~= 0) & (RC = 0)) then do

                if (RESULT = 1) then

                    'OPEN NEW SMART NAME="' || PATH || '/makefile"'
            end
        end
        else
            'REQUEST PROBLEM="' || STRING.sMAKEMAKEERROR || '"'
    end
end

/* ---------------------------- END OF YOUR CODE ----------------------- */

'UNLOCK' /* VERY important: unlock GUI */
EXIT

SYNTAX:

SAY "Sorry, error line" SIGL ":" ERRORTEXT(RC) ":-("
'UNLOCK'
EXIT

/* /// "getprojectname" */

getprojectname: procedure expose CONFIG. STRING. PROJECTNAME OBJFOLDER

    parse upper arg SOFTWARE

    /* try to read project name from options file or makefile */

    PROJECTNAME = ""
    OBJFOLDER   = ""

    call readoptions(SOFTWARE)

    if (PROJECTNAME = "") then do

        call readmakefile(SOFTWARE)

        if (PROJECTNAME = "") then do

            if (SOFTWARE ~= "") then do

                /* try again but ignore specified compiler */

                call readoptions("")

                if (PROJECTNAME = "") then

                    call readmakefile("")
            end
        end
    end

    return

/* /// */
/* /// "readcfg" */

readcfg: procedure expose CONFIG. STRING.

    parse upper arg CMODE

    if (exists("golded:add-ons/c++/compilers/" || CMODE)) then do

        CONFIG.CFG_CONFIG          = "golded:add-ons/c++/compilers/" || CMODE || "/makemake.config"
        CONFIG.CFG_SOFTWARE        = "generic"
        CONFIG.CFG_COMPILERFOLDER  = ""
        CONFIG.CFG_INCLUDE         = ""
        CONFIG.CFG_NDK             = ""
        CONFIG.CFG_COMPILE         = ""
        CONFIG.CFG_LINK            = ""

        /* find configuration file */

        if (exists(CONFIG.CFG_CONFIG) ~= 0) then do

            /* read project configuration */

            R = open('CONFIG', CONFIG.CFG_CONFIG, 'READ')

            if (R = 0) then do

                'REQUEST PROBLEM="' || STRING.sCONFIGREADERR || '"'
            end
            else do

                do forever

                    DATA = readln('CONFIG')

                    if (eof('CONFIG')) then do

                        R = close('CONFIG')

                        leave
                    end
                    else do

                        if (left(DATA, 10) = "[SOFTWARE]") then

                            CONFIG.CFG_SOFTWARE = readln('CONFIG')

                        if (left(DATA, 16) = "[COMPILERFOLDER]") then

                            CONFIG.CFG_COMPILERFOLDER = readln('CONFIG')

                        if (left(DATA, 9) = "[INCLUDE]") then

                            CONFIG.CFG_INCLUDE = readln('CONFIG')

                        if (left(DATA, 5) = "[NDK]") then

                            CONFIG.CFG_NDK = readln('CONFIG')

                        if (left(DATA, 9) = "[COMPILE]") then

                            CONFIG.CFG_COMPILE = readln('CONFIG')

                        if (left(DATA, 6) = "[LINK]") then

                            CONFIG.CFG_LINK = readln('CONFIG')
                    end
                end
            end
        end
        else do

            /* welcome message */

            if (CMODE ~= "GENERIC") then

                STRING.sCONTINUECOMPILER = STRING.sCONTINUE

            'REQUEST TITLE="' || STRING.sCONFIGURATION || ' «' || CMODE || '»"  BODY="' || STRING.sCONFIGHELP || '" BUTTON="' || STRING.sCONTINUECOMPILER || '"'

            if ((RESULT ~= 0) & (RC = 0)) then do

                /* query compiler software */

                if (CMODE = "SAS-C") then

                    SOFTWARE = "SAS/C"

                else if (CMODE = "VBCC") then

                    SOFTWARE = "vbcc"

                else if (CMODE = "GCC") then

                    SOFTWARE = "gcc"

                else if (CMODE = "StormC") then

                    SOFTWARE = "StormC"

                else do

                    'REQLIST VAR=SOFTWARE "SAS/C" "vbcc" "gcc" "DiceC" "StormC" "' || STRING.sOTHER || '"'

                    if ((SOFTWARE = "") | (RC ~= 0)) then do

                        'UNLOCK'

                        exit
                    end
                end

                /* choose defaults */

                SUGGEST_COMPILERFOLDER     = 'sys:'
                SUGGEST_COMPILE            = '<compiler> -<donotlink> %src -<outfile> %obj'
                SUGGEST_LINK               = '<compiler> %objs -<outfile> %exe'
                SUGGEST_INCLUDE            = ''

                if (SOFTWARE = "vbcc") then do

                    CONFIG.CFG_SOFTWARE = "VBCC"

                    SUGGEST_COMPILERFOLDER = 'vbcc:'
                    SUGGEST_COMPILE        = 'vbcc:bin/vc $(shell vbccprefs) -c -o %obj %src'
                    SUGGEST_LINK           = 'vbcc:bin/vc $(shell vbccprefs) -o %exe %objs'
                    SUGGEST_INCLUDE        = 'vincludem68k:'
                end
                else if (SOFTWARE = "gcc") then do

                    CONFIG.CFG_SOFTWARE = "GCC"

                    SUGGEST_COMPILERFOLDER = 'GG:'
                    SUGGEST_COMPILE        = 'gcc $(shell gccprefs) -c -o %obj %src'
                    SUGGEST_LINK           = 'gcc $(shell gccprefs) -o %exe %objs'
                    SUGGEST_INCLUDE        = 'gg:include'
                end
                else if (SOFTWARE = "SAS/C") then do

                    CONFIG.CFG_SOFTWARE = "SAS/C"

                    SUGGEST_COMPILERFOLDER = 'sc:'
                    SUGGEST_COMPILE        = 'sc:c/sc nolink %src'
                    SUGGEST_LINK           = 'sc:c/sc link %objs'
                end
                else if (SOFTWARE = "DiceC") then do

                    CONFIG.CFG_SOFTWARE = "DICE"

                    SUGGEST_COMPILERFOLDER = 'dcc:'
                    SUGGEST_COMPILE        = 'dcc:bin/dcc -2.0 -// -c %src -o %obj'
                    SUGGEST_LINK           = 'dcc:bin/dcc -2.0 -// -o %exe %objs'
                    SUGGEST_INCLUDE        = 'dinclude:'
                end
                else if (SOFTWARE = "StormC") then do

                    CONFIG.CFG_SOFTWARE = "STORMC"

                    SUGGEST_COMPILERFOLDER = "stormc:"
                end
                else
                    CONFIG.CFG_SOFTWARE = "GENERIC"

                /* locate compiler */

                do until CONFIG.CFG_COMPILERFOLDER ~= ""

                    'REQUEST STRING BODY="' || STRING.sCOMPILERFOLDER || '" OLD="' || SUGGEST_COMPILERFOLDER || '" VAR=CONFIG.CFG_COMPILERFOLDER'

                    if ((CONFIG.CFG_COMPILERFOLDER ~= "") & (RC = 0)) then do

                        if (exists(CONFIG.CFG_COMPILERFOLDER) = 0) then do

                            'REQUEST PROBLEM="' || STRING.sCOMPILERMISSING || '"'

                            CONFIG.CFG_COMPILERFOLDER = ""
                        end
                    end
                    else do

                        'UNLOCK'

                        exit
                    end
                end

                /* locate standard includes */

                if (SUGGEST_INCLUDE = "") then do

                    'EXPAND NAME="' || CONFIG.CFG_COMPILERFOLDER || '" VAR=SUGGEST_INCLUDE'

                    if (exists(SUGGEST_INCLUDE || 'include')) then

                        SUGGEST_INCLUDE = SUGGEST_INCLUDE || 'include'
                end

                do until CONFIG.CFG_INCLUDE ~= ""

                    'REQUEST STRING BODY="' || STRING.sSTDHEADER || '" OLD="' || SUGGEST_INCLUDE || '" VAR=CONFIG.CFG_INCLUDE'

                    if ((CONFIG.CFG_INCLUDE ~= "") & (RC = 0)) then do

                        if (exists(CONFIG.CFG_INCLUDE) = 0) then do

                            'REQUEST PROBLEM="' || STRING.sSTDHEADERMISSING || '"'

                            CONFIG.CFG_INCLUDE = ""
                        end
                    end
                    else do

                        'UNLOCK'

                        exit
                    end
                end

                /* locate OS includes */

                do until CONFIG.CFG_NDK ~= ""

                    'REQUEST STRING BODY="' || STRING.sNDKHEADER || '" OLD="golded:add-ons/c++/ndk_39/include/include_h/" VAR=CONFIG.CFG_NDK'

                    if ((CONFIG.CFG_NDK ~= "") & (RC = 0)) then do

                        if (exists(CONFIG.CFG_NDK) = 0) then do

                            'REQUEST PROBLEM="' || STRING.sNDKHEADERMNISSING || '"'

                            CONFIG.CFG_NDK = ""
                        end
                    end
                    else do

                        'UNLOCK'

                        exit
                    end
                end

                /* use built-in configuration for vbcc, gcc and sas/c, otherwise query user */

                if ((CONFIG.CFG_SOFTWARE = "VBCC") | (CONFIG.CFG_SOFTWARE = "SAS/C") | (CONFIG.CFG_SOFTWARE = "SAS/C-GNUMAKE")) then do

                     CONFIG.CFG_COMPILE = SUGGEST_COMPILE
                     CONFIG.CFG_LINK    = SUGGEST_LINK
                end
                else do

                    /* configure compile command */

                    'FIX VAR=SUGGEST_COMPILE'

                    do until CONFIG.CFG_COMPILE ~= ""

                        'REQUEST STRING BODY="' || STRING.sCOMPILE ||'" OLD="' || SUGGEST_COMPILE || '" VAR=CONFIG.CFG_COMPILE'

                        if (RC ~= 0) then do

                            'UNLOCK'

                            exit
                        end
                    end

                    /* configure link command */

                    'FIX VAR=SUGGEST_LINK'

                    do until CONFIG.CFG_LINK ~= ""

                        'REQUEST STRING BODY="' || STRING.sLINK || '" OLD="' || SUGGEST_LINK || '" VAR=CONFIG.CFG_LINK'

                        if (RC ~= 0) then do

                            'UNLOCK'

                            exit
                        end
                    end
                end

                'EXPAND NAME="' || CONFIG.CFG_INCLUDE        || '" VAR=CONFIG.CFG_INCLUDE'
                'EXPAND NAME="' || CONFIG.CFG_COMPILERFOLDER || '" VAR=CONFIG.CFG_COMPILERFOLDER'
                'EXPAND NAME="' || CONFIG.CFG_NDK            || '" VAR=CONFIG.CFG_NDK'

                call savecfg(CMODE)
            end
            else do

                'UNLOCK'

                exit
            end
        end

        /* fix quotes (for using these strings in a command line) */

        'FIX VAR=CONFIG.CFG_COMPILE'
        'FIX VAR=CONFIG.CFG_LINK'
        'FIX VAR=CONFIG.CFG_INCLUDE'
        'FIX VAR=CONFIG.CFG_NDK'
    end
    else do

        'REQUEST PROBLEM="' || STRING.sNOTINSTALLED || " «" || CMODE || '»"'

        'UNLOCK'

        exit
    end

    return

/* /// */
/* /// "savecfg" */

savecfg: procedure expose CONFIG. STRING.

    parse upper arg CMODE

    R = open('CONFIG', CONFIG.CFG_CONFIG, 'WRITE')

    if (R = 0) then do

        'REQUEST PROBLEM="' || STRING.sCONFIGSAVEERR || '"'
    end
    else do

        'QUERY DATE VAR=DATE'

        R = writeln('CONFIG', "[SOFTWARE]")
        R = writeln('CONFIG', CONFIG.CFG_SOFTWARE)
        R = writeln('CONFIG', "[COMPILERFOLDER]")
        R = writeln('CONFIG', CONFIG.CFG_COMPILERFOLDER)
        R = writeln('CONFIG', "[INCLUDE]")
        R = writeln('CONFIG', CONFIG.CFG_INCLUDE)
        R = writeln('CONFIG', "[NDK]")
        R = writeln('CONFIG', CONFIG.CFG_NDK)
        R = writeln('CONFIG', "[COMPILE]")
        R = writeln('CONFIG', CONFIG.CFG_COMPILE)
        R = writeln('CONFIG', "[LINK]")
        R = writeln('CONFIG', CONFIG.CFG_LINK)

        R = close('CONFIG')

        'REQUEST BODY="' || STRING.sCONFIGCREATED1 || "|«" || CMODE || "» " ||  STRING.sCONFIGCREATED2 || '" BUTTON="' || STRING.sOKEDIT || '"'

        if (RESULT = 2) then

            'OPEN NEW SMART NAME="' || CONFIG.CFG_CONFIG || '"'

        if ((RESULT ~= 1) | (RC ~= 0)) then do

            'UNLOCK'

            exit
        end
    end

    return

/* /// */
/* /// "readoptions" */

readoptions: procedure expose CONFIG. STRING. PROJECTNAME OBJFOLDER GSTFILE

    /* read compiler-specific options file in project folder (if any exists) */

    parse upper arg SOFTWARE

    if ((SOFTWARE = "") | (SOFTWARE = "SAS/C") | (SOFTWARE = "SAS/C-GNUMAKE")) then do

        if (exists("scoptions")) then do

            if open('HANDLE', "scoptions", 'READ') then do

                do until eof('HANDLE')

                    DATA = readln('HANDLE')

                    if (upper(left(DATA, 12)) = "PROGRAMNAME=") then do

                        PROJECTNAME = compress(substr(DATA, 13), '"')
                    end
                    else if (left(DATA, 11) = "OBJECTNAME=") then

                        OBJFOLDER = compress(substr(DATA, 12), '"')

                    else if (left(DATA, 18) = "GLOBALSYMBOLTABLE=") then

                        GSTFILE = compress(substr(DATA, 19), '"')
                end

                R = close('HANDLE')
            end
        end
    end

    return

/* /// */
/* /// "saveoptions" */

saveoptions: procedure expose CONFIG. STRING. PROJECTNAME OBJFOLDER

    /* generate compiler-specific options file (only if none exists) */

    parse upper arg SOFTWARE

    if ((SOFTWARE = "SAS/C") | (SOFTWARE = "SAS/C-GNUMAKE")) then do

        if (exists("scoptions") = 0) then do

            R = open('HANDLE', "scoptions", 'WRITE')

            if (R = 0) then do

                'REQUEST PROBLEM="' || STRING.sOPTIONSERR || '"'
            end
            else do

                R = writeln('HANDLE', 'PROGRAMNAME="' || PROJECTNAME || '"')

                if (OBJFOLDER ~= "") then

                    R = writeln('HANDLE', 'OBJECTNAME="'  || OBJFOLDER   || '"')

                R = writeln('HANDLE', 'ERRORREXX')
                R = writeln('HANDLE', 'MODIFIED')
                R = writeln('HANDLE', 'NOLINK')
                R = writeln('HANDLE', 'IDENTIFIERLENGTH=80')
                R = writeln('HANDLE', 'NOICONS')
                R = writeln('HANDLE', 'VERBOSE')

                R = close('HANDLE')
            end
        end
    end
    else if (SOFTWARE = "VBCC") then do

        if (exists("vbcc.options") = 0) then do

            R = open('HANDLE', "vbcc.options", 'WRITE')

            if (R = 0) then do

                'REQUEST PROBLEM="' || STRING.sOPTIONSERR || '"'
            end
            else do

                if (exists("env:vbcc.options")) then do

                    /* duplicate default configuration */

                    R = open('TEMPLATE', "env:vbcc.options", 'READ')

                    if (R = 0) then do

                        'REQUEST PROBLEM="' || STRING.sOPTIONSERR || '"'
                    end
                    else do

                        do until (eof('TEMPLATE'))

                            DATA = readln('TEMPLATE')

                            R = writeln('HANDLE', DATA)
                        end

                        R = close('TEMPLATE')
                    end
                end

                R = close('HANDLE')
            end
        end
    end
    else if (SOFTWARE = "GCC") then do

        if (exists("gcc.options") = 0) then do

            R = open('HANDLE', "gcc.options", 'WRITE')

            if (R = 0) then do

                'REQUEST PROBLEM="' || STRING.sOPTIONSERR || '"'
            end
            else do

                if (exists("env:gcc.options")) then do

                    /* duplicate default configuration */

                    R = open('TEMPLATE', "env:gcc.options", 'READ')

                    if (R = 0) then do

                        'REQUEST PROBLEM="' || STRING.sOPTIONSERR || '"'
                    end
                    else do

                        do until (eof('TEMPLATE'))

                            DATA = readln('TEMPLATE')

                            R = writeln('HANDLE', DATA)
                        end

                        R = close('TEMPLATE')
                    end
                end

                R = close('HANDLE')
            end
        end
    end

    return

/* /// */
/* /// "readmakefile" */

readmakefile: procedure expose CONFIG. STRING. PROJECTNAME

    parse upper arg SOFTWARE

    /* locate makefile */

    MAKEFILE = ""

    if ((SOFTWARE = "") | ((SOFTWARE ~= "SAS/C") & (SOFTWARE ~= "DICE"))) then do

        if (exists("makefile")) then

            MAKEFILE = "makefile"
    end

    if (MAKEFILE = "") then do

        if ((SOFTWARE = "") | (SOFTWARE = "SAS/C")) then do

            if (exists("smakefile")) then

                MAKEFILE = "smakefile"
        end

        if (MAKEFILE = "") then do

            if ((SOFTWARE = "") | (SOFTWARE = "DICE")) then do

                if (exists("dmakefile")) then

                    MAKEFILE = "dmakefile"
            end
        end
    end

    /* try to locate executable name in makefile */

    if (MAKEFILE ~= "") then do

        if (open('HANDLE', MAKEFILE, 'READ') ~= 0) then do

            POS = 0

            do until (eof('HANDLE') | (PROJECTNAME ~= ""))

                DATA = readln('HANDLE')

                if (MAKEFILE = "smakefile") then do

                    if (pos("sc link to", DATA) ~= 0) then do

                        parse var DATA with 'sc' 'link' 'to' '"' PROJECTNAME '"' .

                        if (PROJECTNAME = "") then

                            parse var DATA with 'sc' 'link' 'to' PROJECTNAME .
                    end
                end
                else if (left(DATA, 3) = "EXE") then do

                    parse var DATA with 'EXE' '=' '"' PROJECTNAME '"'.

                    if (PROJECTNAME = "") then

                        parse var DATA with 'EXE' '=' PROJECTNAME .
                end
            end

            R = close('HANDLE')

            PROJECTNAME = compress(PROJECTNAME, '"')
        end
    end

    return

/* /// */